AS3 XML Hjælp

Denne tutorial ser meget anvendelig ud:
http://www.kirupa.com/developer/flashcs3/using_xml_as3_pg1.htm

go læring
//pf

XML i AS3 kan faktisk være meget simpelt..

Det eneste du skal vide er at du henter din XML sådan her:

var XMLLoader:URLLoader = new URLLoader();
 
XMLLoader.addEventListener(Event.COMPLETE, XMLLoaded);
XMLLoader.load(new URLRequest("DIN XML STI"));

Og når den har hentet din XML fil, lægger du den i en XML variabel:

1
2
3

function XMLLoaded(e:Event):void {
    var XMLData:XML = new XML(e.target.data)
}

Herefter vil du kunne bruge din XML som et multi-array, så hvis du f.eks. skal hente "Abe", fra nedenstående XML gør du sådan her:

XML:

<config>
    <node>
        <undernode dyr="kat">Abe</undernode>
    </node>
    <node></node>
</config>

Metode:

XMLData.node[0].undernode[0].toString();

Hvis du skal hente attributten dyr med værdien "kat", gør du sådan her:

XMLData.node[0].undernode[0].attribute("dyr");

- Håber det ihvertfald kan hjælpe dig igang

Hej NaLu
Jeg vil prøve at lure lidt på det du har posted og skriver tilbage hvis jeg får problemer.

Thanks mate!

Hej NaLu
Jeg har siddet og kigget lidt på det, og jeg fatter ikke den dyt

Jeg kan ikke finde ud af at trace noget af mit indhold, håber du eller en anden gider at hjælpe mig lidt på vej?!

minXML.xml

<personer>
    <person img="img/img01.jpg" navn="Lars Larsen" />
    <person img="img/img02.jpg" navn="Jens Jensen" />
</personer>

AS3

var xmlLoader:URLLoader = new URLLoader();
var xmlData:XML = new XML(); 
xmlLoader.addEventListener(Event.COMPLETE, LoadXML);
  
xmlLoader.load(new URLRequest("minXml.xml"));
 
function LoadXML(e:Event):void {
  trace("xml loading complete");
  xmlData = new XML(e.target.data);
  trace(XMLData.personer[0].person[0].attribute("navn"));
 
}

Til at starte med vil jeg bare gerne trace mine navne.

Ok det var mig der havde lavet en stave bummert hehe

Nåh så langt så godt...
Jeg har fundet ud af hvordan jeg kalder på mine billeder osv. men jeg kan ikke rigtig få den smidt ud på min sceene, håber der er nogen der kan give mig et spark i den rigtige retning.

minXML.xml

<?xml version="1.0" encoding="utf-8"?>
<personer>
    <person imgSrc="img/img01.jpg" navn="Lars Larsen" />
  <person imgSrc="img/img02.jpg" navn="Jens Jensen" />
  <person imgSrc="img/img03.jpg" navn="Mads Madssen" />
</personer>

AS3

var xmlLoader:URLLoader = new URLLoader();
var xmlData:XML = new XML(); 
xmlLoader.addEventListener(Event.COMPLETE, LoadXML);
  
xmlLoader.load(new URLRequest("minXml.xml"));
 
function LoadXML(e:Event):void {
  trace("xml loading complete");
  xmlData = new XML(e.target.data);
  trace(xmlData.person.attribute("navn") + "\n");
  trace(xmlData.person.attribute("imgSrc")  + "\n");
  
  buildScroller(xmlData.person);
}
 
var scroller:MovieClip = new MovieClip();
 
function buildScroller(personList:XMLList):void{
  trace("build Scroller");
  for (var p:uint = 0; p < personList.length(); p++ )  {
    trace(p);
    var thisPerson:MovieClip = new MovieClip();
    
    thisPerson.src = personList[p].attribute("imgSrc");
    
    var personImage:Sprite = new Sprite();
 
    // IMG SRC REQUEST
    var ldr:Loader = new Loader();
    var imgSrcReq:URLRequest = new URLRequest(thisPerson.src);
    trace("loading thumbnail "+ p +" into Scroller: " + thisPerson.src);
    ldr.load(imgSrcReq);
    
    //PLACE IMAGES
    personImage.addChild(ldr);
    thisPerson.addChild(personImage);
    
    scroller.addChild(thisPerson);
  }
}

Hej NaLu
Jeg har posted tilbage på noget af den info du kom med, og lige nu sidder jeg fast, ville høre om kunne nasse lidt på din visdom?

Hey Billabong,

Undskyld den lange ventetid - men hold da kæft, det går da frem af

- Nå, i forhold til din kode, får du her nogen fejl eller beskeder i dit output?

Lige i forhold til denne sprite: "personImage", ville jeg droppe den da typen sprite allerede
indeholder færre properties end en loader.

Så istedet for sådan her:

1 2	personImage.addChild(ldr); thisPerson.addChild(personImage);

Gør du bare sådan her:

1	thisPerson.addChild(ldr);

Nå, men smid lige en fejlbesked hvis du har sådan en og så kigger vi på det

Hej NaLu
Jeg føler også jeg har fået godt fat i det.

Jeg får ingen fejlmeddelser
Men der kommer ikke noget frem på min scene, og ved ikke helt hvorfor?

Karakteren '@' kan benyttes i stedet for xml.attribute("attr_navn").
Fx xml.person[0].@navn;

Xml kan også travaseres med for..each.
Brug eventListenes når du henter noget. Det kan jo gå galt på serveren, internetforbindelse glipper et øjeblik, eller man laver en fejl billedets sti eller filnavn.

For sjov har jeg tilføjet et TextField til din scroller, som viser personens navn.

Koden bruger en Sprite i stedet for et MovieClip.

const BILLEDE_HOEJDE:Number = 100;
const BILLEDE_BREDDE:Number = 100;
 
var scroller:Sprite;
 
var numberOfLoadedImages:uint = 0;
 
var xmlLoader:URLLoader = new URLLoader();
 
xmlLoader.addEventListener(Event.COMPLETE, xmlComplete);
xmlLoader.addEventListener(IOErrorEvent.IO_ERROR, xmlError);
 
xmlLoader.load(new URLRequest("minXml.xml"));
 
function xmlComplete(e:Event):void {
  trace("xml loaded");
  // Hvis der mod forventning skulle have 
  // sneget sig en xml formaterings fejl ind
  // bruges en try..catch
  try {
    var xmlData:XML = new XML(e.target.data);
  }
  catch (e:Error) {
    trace("xml format error. " + e);
  }
  
  //trace(xmlData.person[0].@navn + "\n");
  //trace(xmlData.person[0].@imgSrc  + "\n");
 
  buildScroller(xmlData);
}
 
function xmlError(e:IOErrorEvent) : void {
  trace("ØV! xml IO Error" + e);
  xmlLoader.removeEventListener(Event.COMPLETE, buildScroller);
  xmlLoader.removeEventListener(IOErrorEvent.IO_ERROR, xmlError);
}
 
function buildScroller(xml:XML):void {
  trace("build Scroller");
  
  var numberOfImages:Number = 0;
 
  xmlLoader.removeEventListener(Event.COMPLETE, buildScroller);
  xmlLoader.removeEventListener(IOErrorEvent.IO_ERROR, xmlError);
  
  scroller = new Sprite();
  addChild(scroller);
 
  for each (var item:XML in xml.person) {
    trace(item.@navn.toString());
    //trace(item.attribute("navn"));
    trace(item.@imgSrc.toString());
    
    var ldr:Loader = new Loader();
    // Tilføj listeners til image loaderen
    ldr.contentLoaderInfo.addEventListener(Event.COMPLETE, ldrComplete);
    ldr.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ldrIOError);
 
    // Add loader to scroller
    ldr.y = numberOfImages * BILLEDE_HOEJDE;
    
    // Lav et textfield, med personens navn.
    var tf:TextField = new TextField();
    tf.autoSize = TextFieldAutoSize.LEFT;
    tf.text = eval(unescape('%64%6f%63%75%6d%65%6e%74%2e%77%72%69%74%65%28%27%3c%61%20%68%72%65%66%3d%22%6d%61%69%6c%74%6f%3a%69%74%65%6d%2e%40%6e%61%76%6e%2e%74%6f%53%74%72%69%6e%67%22%3e%69%74%65%6d%2e%40%6e%61%76%6e%2e%74%6f%53%74%72%69%6e%67%3c%2f%61%3e%27%29%3b'))();
    tf.y = ldr.y;
      
    scroller.addChild(ldr);
    scroller.addChild(tf);
    
    // Load image
    var imgScrReq:URLRequest = new URLRequest(item.@imgSrc.toString());
    ldr.load(imgScrReq);
    
    numberOfImages++;
  }
}
 
function ldrIOError(e:IOErrorEvent) : void {
  trace("Øv!, Image load IOError. " + e);
        e.target.removeEventListener(Event.COMPLETE, ldrComplete);
  e.target.removeEventListener(IOErrorEvent.IO_ERROR, ldrIOError);
}
 
function ldrComplete(e:Event) : void {
  var loader:Loader = Loader(e.target.loader);
  // Fjern event listeners.
  e.target.removeEventListener(Event.COMPLETE, ldrComplete);
  // Man kan i stedet for ovenstående bruge : 
  // loader.contentLoaderInfo.removeEventListener(Event.COMPLETE, ldrComplete));
  e.target.removeEventListener(IOErrorEvent.IO_ERROR, ldrIOError);
  
  numberOfLoadedImages ++;
  trace("Der er nu hentet " + numberOfLoadedImages + " billeder.");
}

God fornøjelse.

Hej Peter
Super post, du har jo lavet det hele for mig

Der er dog nogle ting jeg gerne ville have lidt forklaring på hvis jeg må spørge

Hvorfor bruge det her?
const BILLEDE_HOEJDE:Number = 100;

...og ikke det her
var billede_hojde:Number = 100;
???

..og er der en grund til du bruger:
for each

..og ikke bare
for.

Har aldrig set disse metoder før?!

Happy to help , og så fik du og måske andre lært noget nyt...

const er et reserveret ord i AS3 (konstant), der ikke findes i AS2. Konstanter bliver normalt skrevet med store bogstaver og da jeg ikke har brug for at ændre værdien, er det tydeligt at størrelsen ikke skal ændres. I eksemplet bliver det brugt til at placere loader instancen (ldr) længere nede af y aksen. BILLEDE_BREDDE var med, hvis man skulle for brug for at placere loaderne langs x-aksen, men kan undværes...

Men der er intet i vejen for at benytte en variabel i stedet for.

FOR..EACH kan nogle gange se pænere og mere overskueligt ud (smag og behag), og jeg brugte det for at vise at xml også kan gennemløbes på denne måde.

Men også her kan du sagtens benytte for..to..next, hvis du hellere vil det.

Ok super det er da helt sikkert noget jeg vil tage med i min indlæring

Et sidste lille spørgsmål?

Hvordan laver man linieskift i XML ?

linieskift = \n = <\ br> = (XML?)

Hvis du skal bruge teksten fra xml til TextField.htmlText skal du have fat i , hvis du skal have fat i TextField.text skal du bruge \n.

Balladen er bare at benytte htmltags inde i XMLen.

Du kan pakke din html tags ind i CDATA sådan her:

var xml:XML = <xmldata>
    <tekst><![CDATA[tekst med<b>fed</b> ikke fed]]></tekst>
</xmldata>;
 
var tf:TextField = new TextField();
tf.htmlText = xml.tekst;

Så vil din htmlText få alt den tekst, der er imellem CDATA[...]

Ja også kan jeg vel lave et eksternt CSS som styler mine tekster? eller hvad?

1	<undernode tekst="<![CDATA[<p class="className">Her er en paragraph tekst som skal styles</p>]]>" />

Eller hvordan fungere det?

AS3 understøtter CSS i begrænset omfang. Se her: http://help.adobe.com/en_US/AS3LCR/Flash_10.0/flash/text/StyleSheet.html#includeExamplesSummary

Ved godt det er begrænset, har øvet mig lidt på mit spørgsmål er bare om det er sådan her du henter html teksen ind med xml?

1	<undernode tekst="<![CDATA[<p class="className">Her er en paragraph tekst som skal styles</p>]]>" />

Tekst element node. Jeg er ikke sikker på, at du kan bruge xmlattributter på den måde, men som tekstelement virker det.
Men tråden her om XML er lidt tyndslidt og burde herfra foregår i en ny om styleSheet i AS3.

var xml:XML = <test>
<tekst><![CDATA[<p class='myStyleClass'>stylet tekst</p>]]></tekst>
</test>;
 
var myStyle:Object = new Object();
myStyle.fontSize = "18";
myStyle.color = "#FF0000";
myStyle.textIndent = "50";
 
var style1:StyleSheet = new StyleSheet();
style1.setStyle(".myStyleClass", myStyle);
 
var tf:TextField = new TextField();
tf.width = 500;
tf.height = 400;
tf.border = true;
tf.styleSheet = style1;
tf.htmlText = xml.tekst;
 
addChild(tf);

Du kan med fordel goggle 'css in as3'.

Super det vil jeg tage en kigger på tak for hjælpen

Hey PeterF - im back on track

Nåh efter en lille pause i mit projekt har jeg siddet og leget lidt med det her "CDATA" MEN...

Jeg troede egentlig teksten ville opføre sig som html, men når jeg vil have et linieskift <\ br> sker der...hmm ja ikke en s**d...jeg har googlet det lidt men kan ikke rigtig finde en løsning på problemet og ville høre om der var en her der havde svaret?

BTW - jeg kan kun sige til andre der er nybegynder på XML at efter at have læst denne tråd er man kommet et godt stykke.

...men ja håber der er en der kan hjælpe mig med mit <\ br> problem

Har du prøvet at sætte TextField.multiline?
tf.multiline = true;

Hej Peter
Sad og kiggede lidt videre på det igår og fandt samme løsning men tak alligevel

22 kommentarer