get medthod return null

Det ville hjælpe at se dine variable erklæringer.

Der er lidt forvirring angående værditildelinger og navne på variabler.

Din parseXML bruger currentTarget i stedet for target.
Du har en variable, der hedder xmlFunction i din setter method. Tænk på om functionen måske skal være public! (Drop setter method)
Du har en variable, der hedder Xml (med stort X) i din getter method.
Den skal være public.
Vær opmærksom på konsekvenser af private, internal, protected og public, når du skal udvide klasser.

Eksemplet herunder dispatcher en Event, når xml er hentet.

package xmltest
{
  import flash.net.*;
  import flash.events.*;
  import flash.errors.*;
  
  public class XMLLoader extends EventDispatcher
  {
    private var _xml:XML;
    
    // Constructor
    public function XMLLoader()
    {
      _xml = null;
    }
    
    public function load(url:String) : void
    {
      var urlRequest:URLRequest = new URLRequest(url);
      var urlLoader:URLLoader = new URLLoader();
    
      urlLoader.addEventListener(Event.COMPLETE, xmlLoaded);
      // Hvis nu det går galt, så tjek hvad det var. fx med nedenstående.
      // urlLoader.addEventListener(IOErrorEvent.IO_ERROR, xmlIOError);
      // urlLoader.addEventListener(SecurityErrorEvent.SECURITY_ERROR, xmlSecurityError);
      urlLoader.load(urlRequest);
    }
    
    private function xmlLoaded(e:Event) : void
    {
        _xml = XML(e.target.data);
      trace("XMLLoader: xml loaded.");
      dispatchEvent(new Event("XMLLoaded", true));
    }
    
    public function get xml() : XML
    {
      return _xml;
    }
  }
}

Du kan test klassen i et frame script i en ny FLA fil sådan:

import xmltest.XMLLoader;
 
var xmlLoader:XMLLoader = new XMLLoader();
xmlLoader.addEventListener("XMLLoaded", xmlReady);
xmlLoader.load("test.xml");
 
function xmlReady(e:Event) : void
{
  var loader:XMLLoader = XMLLoader(e.target);
  var xml:XML = loader.xml;
  trace("xml = " + xml.toString());
}

get medthod return null

2 kommentarer