anchor point position scaling

8 kommentarer

evt. læg textfield i mc m. reg. point center

jeg har en millionen text felter jeg skal gøre det med derfor jeg tager de gennem displaylist - men ja jeg ku godt lave et sprite in runchime

http://www.oscartrelles.com/archives/dynamic_movieclip_registration_with...
burde vel virke på textfields også, såfremt det defineres.

ok - løsning var den mest crasy jeg nogen sinde har regnet mig frem til -

mit udgangs punkt med at bare trække halvdelen af width fra når jeg scaler op og ned var som sådan fin nok selvom det ik virkede - så efter jeg har kuglegravet alt omlæggende matematik og lagt det ind containers fandt jeg ved en fejl frem til at løsning så sådan her ud selvom det ikke giver noget logisk menig

1
2
3

myTextField.scaleX = myTextField.scaleY = scaleFactor //slider_obj.value;
myTextField.x = -myTextField.width*1.52
myTextField.y = -myTextField.height/2

some brain please explain!

på y aksen virker det fint men på x aksen skal den ha -*1.52 WTF *!)"&%#=!*

*edit*

det lader til 1.52 er dynamisk alt efter størrelsen så jeg arbejder på at finde en formel der kan gengive den rette scaleVærdi omregnet fra den egen width and height

Du har ret, Thonbo - det virker umådeligt ulogisk, samt bare forkert! Og ak ja, mennesker ved sgutte engang 4%, resten skal der ledes efter i de sorte huller - men du har vel ikke en fla, der åbenbarer - din påstand?

jo jo -

http://thonbo.com/test/sizeTest.html

http://thonbo.com/test/sizeTest.fla

og lige prøvet med getBounds og getRect og transform.matrix.pixelBounds.width

og nyt matrix object med tx og ty i stedet for x og y - same result

og textWidth er ikke tilgængelig på StaticTextfield

StaticText er noget værre noget rent positionsmæssigt. Har kløet mig til blods bag ørene.

Men det kan lade sig gøre at transformere dit StaticText til TextField! Hm, hmm.
Det burde gøre det muligt at skalere normalt.

I Library skal den font, du bruger, embeddes.
Hvis du på stage fx har en instance af et StaticText med fonten fra Library, kan man pludselig gøre således:

var st:TextField = TextField(getChildAt(0)); // !!!!

Vær dog opmærksom på, at TextField.text indeholder en mellemrumskarakter i slutningen af strengen.

Eksemplet herunder forudsætter
A: en en embedded font i Library (ActionScript og export in first frame.),
B: Slider Component på stage (instance name = "slider".
C: og en enkel instance af StaticText der bruger embbeded fonten i Library. Left Justified.
D: kode placeres på frame 1.

Link til flash CS3 eksempel StaticText_cs3.fla

import flash.display.*;
import flash.text.*;
import flash.events.*;
import fl.events.SliderEvent;
import fl.controls.Slider;
 
// The StaticText instance on stage converted to TextField!!!
var st:TextField; 
 
loaderInfo.addEventListener(Event.INIT, initListener);
 
function initListener(e:Event) : void
{
  if (getChildAt(0) is TextField)
  {
    st = TextField(getChildAt(0));
  }
  
  //trace(st.text.length); // !! one char longer than expected...
  
  var textGutter : Number = 2;
 
  // Set width according to text in the StaticText (now TextField)
  st.width =  st.textWidth + (textGutter * 2);
  
  // Draw a TextField boundingbox before scaling.
  var centerX:Number = getCenterX(st);
  var centerY:Number = getCenterY(st);
  drawRectangle(centerX - (st.width / 2), centerY - (st.height / 2), st.width, st.height);
  
  slider.addEventListener(SliderEvent.CHANGE, scaleChange);
}
 
function scaleChange(e:SliderEvent) : void
{
  var centerX:Number = getCenterX(st);
  var centerY:Number = getCenterY(st);
 
  centerScale(st, e.value);
  
  // Draw a new boundingbox after scaling on Stage.
  drawRectangle(centerX - (st.width / 2), centerY - (st.height / 2), st.width, st.height);
}
 
// Returns the given DisplayObjects center x (anchor)
function getCenterX(obj:DisplayObject) : Number
{
  return obj.x + (obj.width / 2);
}
// Returns the given DisplayObjects center y (anchor)
function getCenterY(obj:DisplayObject) : Number
{
  return obj.y + (obj.height / 2);
}
 
// Scales a given displayObject from center with a given scaleFactor.
function centerScale(dObj:DisplayObject, scaleFactor:Number) : void
{
  // Save current centerPoint
  var centerX:Number = getCenterX(dObj);
  var centerY:Number = getCenterY(dObj);
  
  // Scale with the DisplayObject
  dObj.scaleX = dObj.scaleY = scaleFactor;
  
  // Reposition DisplayObject
  dObj.x = centerX - (dObj.width / 2);
  dObj.y = centerY - (dObj.height / 2);
}
 
// Draws a rectangle on stage (root)
function drawRectangle(x:Number, y:Number, w:Number, h:Number) : void
{
  graphics.lineStyle(1.0, 0x000000, 1.0);
  graphics.drawRect(x,y,w,h);
}