Skubbe til andre Mc | FlashForum

lavede et hurtigt eksempel til dig.

copy og paste det ind i en tom fla

var buttons:Array = new Array();
var numOfButtons:Number = 5;
var button_width:Number = 50;
var button_height:Number = 20;
 
for(var i:Number = 0; i<numOfButtons; i++){
  var button:Sprite = new Sprite();
  button.graphics.beginFill(0x0000ff);
  button.graphics.drawRect(-button_width*0.5, -button_height,button_width, button_height);
  button.graphics.endFill();
  buttons.push(button);
  addChild(button);
  button.addEventListener(MouseEvent.MOUSE_OVER, buttonOver);
  button.addEventListener(MouseEvent.MOUSE_OUT, buttonOut);
  button.x = 150+(i*(button_width+5));
  button.y = 200;
  }
  
function findArrayPos(target:Sprite):Number{
  var arrayPos:Number;
    for(var i:Number = 0; i<buttons.length; i++){
      if(buttons[i] == target){
        arrayPos = i;
        }
      }
  return arrayPos;
  }
 
function buttonOver(e:Event):void{
    var arrayPos:Number = findArrayPos(Sprite(e.target));
    buttons[arrayPos].scaleX = 1.5;
    buttons[arrayPos].scaleY = 1.5;
    if(arrayPos != 0){
      for(var b:Number = arrayPos; b>0; b--){
        buttons[b-1].x-=button_width*0.25;
        } 
      }
    if(arrayPos != buttons.length-1){
      for(var f:Number = arrayPos; f<buttons.length-1; f++){
        buttons[f+1].x+=button_width*0.25;
        } 
      }
    }
function buttonOut(e:Event):void{
    var arrayPos:Number = findArrayPos(Sprite(e.target));
    buttons[arrayPos].scaleX = 1;
    buttons[arrayPos].scaleY = 1;
    if(arrayPos != 0){
      for(var b:Number = arrayPos; b>0; b--){
        buttons[b-1].x+=button_width*0.25;
        } 
      }
    if(arrayPos != buttons.length-1){
      for(var f:Number = arrayPos; f<buttons.length-1; f++){
        buttons[f+1].x-=button_width*0.25;
        } 
      }
    
    }

det første forloop laver knapperne og er som sådan ikke særlig vigtig. Det vigtigste er at du har alle dine knapper i et array i den orden de ligger på scenen.
På den måde kan du nemlig finde alle knapperne på henholdsvis venstre og højre side(eller op og ned for den sags skyld) og tilpasse dem så de er på den rigtige position i forhold til den forstørrede knap.

Næste skridt ville være at tage din ynglings tween engine og tweene repositioneringen og skaleringen af knapperne

4 kommentarer

Fuck man...troede faktisk det var umuligt:D

skal prøve at få det til a fungere:D

Thanks

fortsat go weekende:D

"alt kan lade sige gøre i Flash" - fiduzen

Afdelingen for Petitesser og kodeoptimering oplyser og undskylder på forhånd denne kommentar og off topic.
Det er kun til orientering og velvidende at ovenstående eksempel er hurtigt lavet.

Array har faktisk en metode, der hedder function Array.indexOf(searchElement:*, fromIndex:int = 0):int, der returnerer targets index i array'et. Hvis target ikke bliver fundet, returneres -1.
Man kunne undlade function findArrayPos() : Number! og erstatte kaldene med

var arrayPos:int = buttons.indexOf(e.target);

VH
Peter