Placering af MovieClips i Fullscreen Flash

// sæt (0,0) registreringspunktet til at være i øverste venstre hjørne
Stage.align = "TL";
 
// sæt scaleMode til noScale, så indholdet i swf'en ikke kan skaleres
Stage.scaleMode = "noScale";
 
var sizeListener:Object = new Object();
 
// denne funktion bliver kaldt hver gang swf'en ændre størrelse
sizeListener.onResize = function() {
  // find bredden og højden af swf'en
  var sw:Number = Stage.width;
  var sh:Number = Stage.height;
 
  // øverste venstre hjørne:
  // x-koordinaten skal bare være 0
  // y-koordinaten skal bare være 0
  topLeft_mc._x = 0;
  topLeft_mc._y = 0;
 
  // øverste højre hjørne:
  // x-koordinaten skal være bredden af swf'en minus bredden af mc'et
  // y-koordinaten skal bare være 0
  topRight_mc._x = sw-topRight_mc._width;
  topRight_mc._y = 0;
 
  // nederste venstre hjørne:
  // x-koordinaten skal bare være 0
  // y-koordinaten skal være højden af swf'en minus højden af mc'et
  bottomLeft_mc._x = 0;
  bottomLeft_mc._y = sh-bottomLeft_mc._height;
 
  // nederste højre hjørne:
  // x-koordinaten skal være bredden af swf'en minus bredden af mc'et
  // y-koordinaten skal være højden af swf'en minus højden af mc'et
  bottomRight_mc._x = sw-bottomRight_mc._width;
  bottomRight_mc._y = sh-bottomRight_mc._height;
 
  // midt i:
  // x-koordinaten skal være bredden af swf'en divideret med 2, minus bredden af mc'et divideret med 2
  // y-koordinaten skal være højden af swf'en divideret med 2, minus højden af mc'et divideret med 2
  center_mc._x = sw/2-center_mc._width/2;
  center_mc._y = sh/2-center_mc._height/2;
 
  // fortæl flash at den skal opdatere scenen
  updateAfterEvent();
};
 
// tilføj et listener objekt, som opdager når swf'en bliver resizet
Stage.addListener(sizeListener);
 
// kald funktion en gang så alle movieclips bliver placeret korrekt
sizeListener.onResize();